home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / demo1056.cir < prev    next >
Encoding:
Text File  |  1996-07-09  |  4.1 KB  |  119 lines
  1. LT1056 Asymmetric SR Demo (Output = V(55))
  2. *
  3. *                            Walt Jung
  4. *            LT1056 asymmetric slewing JFET op amp macromodel
  5. *                            06/28/90
  6. *
  7. * This circuit is an example of one which some might first assume
  8. * to be trivial.  It is, after all, just a picture of an op amp
  9. * slewing!  But, in consideration of the past modeling of P
  10. * channel JFET input op amps such as LF355/56 and OP15/16
  11. * families, maybe it is not trivial at all.  This is for the
  12. * simple reason that the asymmetric slew characteristics of this
  13. * very popular class of op amps has not been properly modeled 
  14. * heretofore!
  15. *
  16. * This circuit is a simple voltage follower, set up for the
  17. * same conditions as the data sheet test circuit for the LT1056.
  18. * This op amp is a precision JFET input op amp, one topologically
  19. * related to the LF156/356 and OP16 types.  The actual device slew 
  20. * response is shown on p 2-223 (top left) of the LTC 1990 data book.  
  21. * Like the real device, the simulation here exhibits a positive slew 
  22. * rate of about 1/2 that of the negative slew.
  23. *
  24. * In this demo, the Probe CMD file supplied calls up display parameters
  25. * which show a single plot of the LT1056 output.
  26. *
  27. .OPT ACCT LIST NODE OPTS NOPAGE
  28. .WIDTH OUT=80 
  29. .TEMP 27 
  30. .TRAN 1US 5US
  31. VIN 2 0 AC 1 PULSE (-10 10 1us .01US .01US 2US 4US)
  32. .PROBE 
  33. .IC V(55)=0             
  34. * 
  35. VCC   52    0 +15V
  36. VEE   53    0 -15V
  37. R1    51   55 1
  38. R2    2    50 1
  39. Cl    55   0  100pF
  40. *     (+) (-)  V+  V-  OUT
  41. XU1   50  51  52  53  55  LT1056
  42. *
  43. .SUBCKT LT1056 3 2 7 4 6
  44. VCM2 40 4 2.0000E+00
  45. RD1 40 80 9.6458E+02
  46. RD2 40 90 9.6458E+02
  47. J1 80 102 12 JM1 
  48. J2 90 103 12 JM2 
  49. CIN 2 3 4.0000E-12
  50. RG1 2 102 2.0000E+00
  51. RG2 3 103 2.0000E+00
  52. C1 80 90 1.5000E-11
  53. ISS 7 12 5.6000E-04
  54. GOSIT 7 12 90 80 2.8000E-04
  55. GCM 0 8 12 0 1.3052E-08
  56. GA 8 0 80 90 1.0367E-03
  57. R2 8 0 1.0000E+05
  58. C2 1 8 3.0000E-11
  59. GB 1 0 8 0 7.8368E+01
  60. RO2 1 0 4.9000E+01
  61. RSO 1 6 1.0000E+00
  62. ECL 18 0 1 6 1.7377E+01
  63. GCL 0 8 20 0 1.0000E+00
  64. RCL 20 0 1.0000E+03
  65. D1 18 20 DM1 
  66. D2 20 18 DM1 
  67. D3A 131 70 DM3 
  68. D3B 13 131 DM3 
  69. GPL 0 8 70 7 1.0000E+00
  70. VC 13 6 2.9595E+00
  71. RPLA 7 70 1.0000E+04
  72. RPLB 7 131 1.0000E+05
  73. D4A 60 141 DM3 
  74. D4B 141 14 DM3 
  75. GNL 0 8 60 4 1.0000E+00
  76. VE 6 14 2.9595E+00
  77. RNLA 60 4 1.0000E+04
  78. RNLB 141 4 1.0000E+05
  79. IP 7 4 4.4400E-03
  80. DSUB 4 7 DM2 
  81. .MODEL JM1 PJF (IS=1.1000E-11 BETA=9.5964E-04 VTO=-1.000000E+00)
  82. .MODEL JM2 PJF (IS=9.0000E-12 BETA=9.5964E-04 VTO=-9.998600E-01)
  83. .MODEL DM1 D (IS=1.0000E-15)
  84. .MODEL DM2 D (IS=8.0000E-16 BV=4.8000E+01)
  85. .MODEL DM3 D (IS=1.0000E-16)
  86. .MODEL DM4 D (IS=1.0000E-09)
  87. .ENDS LT1056
  88. **
  89. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1990
  90. *                       All rights reserved.
  91. * 
  92. *   Linear Technology Corporation hereby grants the users of this
  93. * macromodel a non-exclusive, nontransferrable license to use this
  94. *            macromodel under the following conditions:
  95. * 
  96. * The user agrees that this macromodel is licensed from Linear
  97. * Technology and agrees that the macromodel may be used, loaned,
  98. * given away or included in other model libraries as long as this
  99. * notice and the model in its entirety and unchanged is included.
  100. * No right to make derivative works or modifications to the
  101. * macromodel is granted hereby.  All such rights are reserved.
  102. * 
  103. * This model is provided as is.  Linear Technology makes no
  104. * warranty, either expressed or implied about the suitability or
  105. * fitness of this model for any particular purpose.  In no event
  106. * will Linear Technology be liable for special, collateral,
  107. * incidental or consequential damages in connection with or arising
  108. * out of the use of this macromodel.  It should be remembered that
  109. * models are a simplification of the actual circuit.
  110. * 
  111. * Linear Technology reserves the right to change these macromodels
  112. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  113. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  114. * datasheets on the actual amplifiers or the latest macromodels.
  115. * 
  116. * ----------------------------------------------------------------------- *
  117. .END
  118. 
  119.